(DTPtechNote:1213) [AS Indesign CS & Photoshop CS] リサイズして再リンク

[市川せうぞー <anonymous at unknown-host>]

とにかくおうち使い用。
グラフィックフレームを選択して、実寸で所定の解像度にリサイズして再リンクするのだけど、
かなり危険。どれくらい危険かというと、、
・実効解像度の判定をしていない（大きな画像を小さくリサイズする用途なので）
・単位系は全く考慮しない（デフォルト設定に従う）
・画像の縦横比が異なってもOK^^（だってそういう仕事だから）
　#これはfitのオプションをかえればいいだけだけど、とにかく比率を変えるという「仕事」なので^^
・もろもろエラー処理はまったくしていない。

set my_resolution to 200 --原寸200dpi

tell application "InDesign CS_J"
	activate
	tell document 1
		set my_every_selection to object reference of selection
		repeat with my_selection in my_every_selection
			--グラフィックフレームの情報
			tell my_selection
				set tmp_bounds to geometric bounds
				set frame_x to (item 4 of tmp_bounds) - (item 2 of tmp_bounds)
				set frame_y to (item 3 of tmp_bounds) - (item 1 of tmp_bounds)
			end tell
			--グラフィックそのものを編集
			set my_image to object reference of item 1 of all graphics of my_selection
			edit original item link of my_image
			my resize_image(frame_x, frame_y, my_resolution)
			update item link of my_image
			fit my_selection given content to frame --内容をフレームに合わせる（今回だけの仕様）
		end repeat
	end tell
end tell

--photoshopでリサイズ
to resize_image(frame_x, frame_y, my_resolution)
	tell application "Adobe Photoshop CS"
		--activate
		if frame_x > frame_y then
			resize image document 1 width frame_x resolution my_resolution resample method bicubic
		else
			resize image document 1 height frame_y resolution my_resolution resample method bicubic
		end if
		close document 1 saving yes
	end tell
end resize_image