(DTPtechNote:1089) [AS_InDesign CS] paste text.as

[市川せうぞー <anonymous at unknown-host>]

(*
paste text.as
コピーした文字列のプレーンテキストだけをペーストします。
アプリケーション:Adobe InDesign CS_J:Presets:Scripts:
フォルダに入れて、スクリプトパレットからつかってください。
2005.03.23	 www.seuzo.jp
*)
tell application "InDesign CS_J"
	activate
	
	--クリップボードの確認と取り込み
	if (clipboard info for string) is not {} then --クリップボードのテキストが空でなかったら
		set clip_str to (the clipboard) as Unicode text --変数にセットしちゃう
	else
		my my_error("クリップボードが空です", true) --クリップボードが空なら中止
	end if
	
	
	--確認
	if (not (exists selection)) or class of selection is not text then
		my my_error("カーソルが挿入位置にありません", true) --セル以外を選択しているなら中止
	end if
	
	--実行
	try
		set contents of selection to clip_str
	on error errMsg number errNum
		my my_error(errMsg & return & errNum, true) --エラーが起こったら中止
	end try
	
end tell



----------------------------------●エラー処理
on my_error(err_str, my_stop)
	if my_stop then
		set my_stop to {"中止"}
	else
		set my_stop to {"中止", "続行"}
	end if
	tell application "InDesign CS_J"
		activate
		set ans to button returned of (display dialog err_str buttons my_stop with icon stop) --警告ダイアログ出してストップ
		if ans is "中止" then error number -128
	end tell
end my_error